Igapäevasel MS Windowsi kasutamisel keelame uuendused ära -
nii on rahulikum töötada ja ei katkestada meid võibolla ebasobival hetkel.

Vaid siis kui vaja uuendusi teha, esmalt lubame need
ja siis käivitame uuendamise juba tavapäraselt,
lisainfo:
https://support.microsoft.com/et-ee/help/4027667/windows-update-windows-10

Peale uuenduste tegemist tuleks uuendamine taas keelata.

Avada CMD superkasutaja õigustes
--------------------------------
* Super+R
* runas /user:Administrator cmd

Veel erinevaid viise cmd avamiseks superkasutajana:
https://www.howtogeek.com/194041/how-to-open-the-command-prompt-as-administrator-in-windows-8.1/
https://www.askvg.com/guide-different-ways-to-open-command-prompt-as-administrator-in-windows/
https://helpdeskgeek.com/how-to/command-prompt-admin-rights-windows/

Kasutaja Administrator võib olla mistahes superkasutaja õigustes olev
kasutaja - asendada õigega.

Superkasutaja - haldamisõigustes olev kasutaja
Super-klahv - tihti MS Windowsi logoga klahv

Viited:
https://en.wikipedia.org/wiki/Superuser
https://en.wikipedia.org/wiki/Super_key_(keyboard_button)
https://en.wikipedia.org/wiki/Windows_key

KEELAMINE
---------
https://fossbytes.com/stop-disable-windows-10-forced-updates-command/

Nimed:
Windows Update (wuauserv)
Background Intelligent Transfer Service (bits)
Delivery Optimization (dosvc)

teenuste käivitustüübi vaatamine:
sc qc wuauserv | findstr -I start_type
sc qc bits | findstr -I start_type
sc qc dosvc | findstr -I start_type

tihti on käivitustüübid:
wuauserv: DEMAND_START
bits AUTO_START (DELAYED)
dosvc AUTO_START (DELAYED)

START_TYPE
DEMAND_START -> manual
AUTO_START -> automatic
AUTO_START (DELAYED) -> automatic (delayed)
DISABLED -> disabled

* * *

teenuse oleku vaatamine:
sc query wuauserv | findstr -I state
sc query bits | findstr -I state
sc query dosvc | findstr -I state

tihti on olekud:
wuauserv: STOPPED
bits: RUNNING
dosvc: STOPPED

vajadusel teenuste seiskamine:
sc stop wuauserv
sc stop bits
sc stop dosvc

võib kasutada ka:
net stop wuauserv
net stop bits
net stop dosvc

kui teenus juba seisab siis tuleb ka vastav teade, et teenust ei olnud
käivitatud ja ei saa seisma panna kuna juba seisab:
[SC] ControlService FAILED 1062:
The service has not been started.

peale seiskamist kontrollida uuesti kas on seiskunud
(vt teenuse oleku vaatamine) - kõikide olekud peavad olema STOPPED

teenuste keelamine:
sc config wuauserv start= disabled
sc config bits start= disabled
sc config dosvc start= disabled

oleku vaatamine:
sc query wuauserv
sc query bits
sc query dosvc

LUBAMINE
--------
teenuste lubamine esialgsete olekute peale:
sc config wuauserv start= demand
sc config bits start= delayed-auto
sc config dosvc start= delayed-auto

kontrolliks teenuste käivitustüübi vaatamine:
sc qc wuauserv | findstr -I start_type
sc qc bits | findstr -I start_type
sc qc dosvc | findstr -I start_type

tihti on käivitustüübid:
wuauserv: DEMAND_START
bits AUTO_START (DELAYED)
dosvc AUTO_START (DELAYED)

START_TYPE
DEMAND_START -> manual
AUTO_START -> automatic
AUTO_START (DELAYED) -> automatic (delayed)
DISABLED -> disabled

* * *

vajadusel teenuste käivitamine:
sc start wuauserv
sc start bits
sc start dosvc

tihti on olekud:
wuauserv: STOPPED (seega ei ole vaja ise käsitsi käivitada)
bits: RUNNING
dosvc: STOPPED (seega ei ole vaja ise käsitsi käivitada)

olekute vaatamine:
sc query wuauserv | findstr -I state
sc query bits | findstr -I state
sc query dosvc | findstr -I state

* * *

teenuse nime pärimine lühinime alusel:
sc GetDisplayName SERVICE_NAME

...asendada SERVICE_NAME tegeliku teenuse nimega.

# # #

SKRIPTID
Tegevuse lihtsustamiseks on mõistlik kirjutada käsud tekstifaili, iga
käsk uuelt realt ning neid siis ka faili käivitamisel vastavalt
käivitatakse. Fail salvestada laiendiga .bat (saab käivitada kui
programmi) ja veenduda selles - lubada failitüüpide näitamine
(http://kb.winzip.com/kb/entry/26/) - eemaldada valik "Hide file
extensions for known file types" eest - siis näeme ka failitüüpi .bat
Kui me seda ei muuta siis tekib topeltfailitüüp .bat.txt ja seda ei saa
käima panna kui programmi. Kui salvestada Notepad'iga .bat faili siis
tuleb failitüübiks määrata "All files (*.*)" ja failinime lahtrisse ise
meelevaldselt kirjutada failinimi.bat kus "failinimi" siis asendada
soovitud failinimega.
.bat faili saab muuta kui teha failil hiire paremklõps ja valida "Edit".
Valikud sõltuvad MS Windowsi keelest.

Microsofti Notepad'i asemel on soovitav kasutada Notepad3
https://www.rizonesoft.com/introducing-notepad3/
https://www.rizonesoft.com/downloads/notepad3/
https://github.com/rizonesoft/Notepad3/releases
Paigaldamisel on soovitav märkida MS Windowsi Notepadi asendamine -
siis edaspidi avatakse kõik sobivad failid juba uue Notepad3'ga.

nul suunab väljundi "musta auku", mõnel juhul vaja veavoog (2)
eraldi suunata.

Uuendamise keelamise/lubamise skriptid tuleb käivitada superkasutaja
õigustes. Seda saab teha ka hiire paremklahvi alt "Run as administrator"
Kui ollakse sisse loginud superkasutaja õigustes oleva kasutajaga
siis saab otse käivitada.

Skriptid on soovitav panna näiteks dokumentide kausta ja
võib teha lingid töölauale - nii on lihtne kiirelt neid käivitada.

keelame-uuendused.bat
---------------------
@ECHO OFF
REM paneme kindluse mõttes teenused seisma juhul kui mõni neist ka
REM töötas ja suuname veateated "musta auku"
sc stop wuauserv > nul 2> nul
sc stop bits > nul 2> nul
sc stop dosvc > nul 2> nul
echo.
echo.
echo Paus 5 sekundit, ootame teenuste seiskumist...
ping 127.0.0.1 -n 6 > nul 2> nul
echo.
echo.
REM teenuste keelamine
echo.
sc config wuauserv start= disabled > nul 2> nul
sc config bits start= disabled > nul 2> nul
sc config dosvc start= disabled > nul 2> nul
echo.
echo.
cls
echo.
echo Teenuste edaspidine ka:ivitamine on keelatud:
echo.
echo Windows Update (wuauserv):
sc qc wuauserv | findstr -I start_type
echo.
echo Background Intelligent Transfer Service (bits):
sc qc bits | findstr -I start_type
echo.
echo Delivery Optimization (dosvc):
sc qc dosvc | findstr -I start_type
echo.
echo #############################################
echo.
echo Siin peaks teenused olema keelatud ehk siis ka:ivitusolekuga:
echo		START_TYPE : 4 DISABLED
echo.
echo.
pause
cls
echo.
REM Kuvame teenuste hetkeolekud:
echo.
echo Windows Update (wuauserv):
sc query wuauserv | findstr -I state
echo.
echo Background Intelligent Transfer Service (bits):
sc query bits | findstr -I state
echo.
echo Delivery Optimization (dosvc):
sc query dosvc | findstr -I state
echo.
echo #############################################
echo.
echo Siin peaks teenused olema seiskunud ehk siis olekuga:
echo		STATE : 1 STOPPED
echo.
echo.
echo Sellega on MS Windowsi uuendused keelatud!
echo.
echo.
pause

* * *

lubame-uuendused.bat
--------------------
@ECHO OFF
echo.
REM Lubame esmalt teenused esialgsete olekute peale
echo.
sc config wuauserv start= demand > nul 2> nul
sc config bits start= delayed-auto > nul 2> nul
sc config dosvc start= delayed-auto > nul 2> nul
echo.
echo.
REM Seejärel paneme esialgsete olekute peale tööle
echo.
sc start bits > nul 2> nul
echo.
echo.
cls
echo.
echo Teenuste edaspidine ka:ivitamine on lubatud:
echo.
echo Windows Update (wuauserv):
sc qc wuauserv | findstr -I start_type
echo.
echo Background Intelligent Transfer Service (bits):
sc qc bits | findstr -I start_type
echo.
echo Delivery Optimization (dosvc):
sc qc dosvc | findstr -I start_type
echo.
echo #############################################
echo.
echo Siin peaks teenused olema ka:ivitusolekutega:
echo.
echo wuauserv:	START_TYPE : 3 DEMAND_START
echo bits:		START_TYPE : 2 AUTO_START (DELAYED)
echo dosvc:		START_TYPE : 2 AUTO_START (DELAYED)
echo.
echo.
pause
cls
echo.
REM Kuvame teenuste hetkeolekud:
echo.
echo Windows Update (wuauserv):
sc query wuauserv | findstr -I state
echo.
echo Background Intelligent Transfer Service (bits):
sc query bits | findstr -I state
echo.
echo Delivery Optimization (dosvc):
sc query dosvc | findstr -I state
echo.
echo #############################################
echo.
echo Siin peaks teenused olema olekuga
echo wuauserv:	STATE : 1 STOPPED
echo bits:		STATE : 4 RUNNING
echo dosvc:		STATE : 1 STOPPED
echo.
echo.
echo Sellega on MS Windowsi uuendused lubatud!
echo.
echo.
pause

* * *

Siin kontrollskript, mis näitab vastavate teenuste
käivitus- ja hetkeolekuid. Seda hea käivitada kui ei ole kindel
kas nüüd uuendused on lubatud/keelatud või mitte.

kontroll.bat
------------
@ECHO OFF
cls
echo.
echo Teenuste ka:ivitusolekud:
echo.
echo Windows Update (wuauserv):
sc qc wuauserv | findstr -I start_type
echo.
echo Background Intelligent Transfer Service (bits):
sc qc bits | findstr -I start_type
echo.
echo Delivery Optimization (dosvc):
sc qc dosvc | findstr -I start_type
echo.
echo #############################################
echo.
echo Kui teenuse ka:ivitusolek on:
echo.
echo 		START_TYPE : 3 DEMAND_START
echo vo:i ka
echo 		START_TYPE : 2 AUTO_START (DELAYED)
echo.
echo .... siis on uuendamine lubatud
echo.
echo Kui aga:
echo		START_TYPE : 4 DISABLED
echo.
echo .... siis on uuendamine keelatud.
echo.
pause
cls
echo.
REM Kuvame teenuste hetkeolekud:
echo.
echo Windows Update (wuauserv):
sc query wuauserv | findstr -I state
echo.
echo Background Intelligent Transfer Service (bits):
sc query bits | findstr -I state
echo.
echo Delivery Optimization (dosvc):
sc query dosvc | findstr -I state
echo.
echo #############################################
echo.
echo Kui on:
echo STATE : 4 RUNNING - teenus hetkel to:o:tamas
echo.
echo STATE : 3 STOP_PENDING - teenust pannakse veel seisma
echo.
echo.
echo Kui aga:
echo		STATE : 1 STOPPED
echo.
echo .... siis on teenus hetkel seiskunud.
echo Kui teenus seisab siis ei ole sellest midagi
echo kui ka:ivitusolek lubab teenusel vajadusel ka:ima minna.
echo.
pause